SCENE 1000 forest, SCENE, "Gate to the Mysterious Forest"
GIVE L9999
GIVE M9999
ACTOR 1, "Forest Guard", campguard, 1,30,70
IF T3000, @pass
1: Welcome....
IF GS, @warmwelcome
1: It appears that you are.. lacking a Golden Soul...
1: Well then, if you wish to proceed any further, you must beat me in a duel.
1: Do you wish to fight?
ASK 9999
IF YES, @fight
1: A wise decision. Farewell.
MOVE 1,-100,70
END

@fight
SEL 1
POSE 4
1: As you wish...
WAIT 2
SEL 1
POSE 2
1: Let's fight!
WAIT 1.5
MOVE 1,-100,-100,1
FIGHT 510
IF WIN, @win
MOVE 1,30,70,1
SEL 1
POSE 1
1: You cannot win.
1: Get a golden soul, then return.
MOVE 1,-100,70
END

@win
1: Ahh.. I see you have won..
H: If you let me pass, you may live!
1: Yes, yes, go right ahead...
SEL 1
POSE 2
1: This is NOT my day....
MOVE 1,-100,70
WAIT 5
H: Alright, now I can get deeper within the forest!
H: I wonder what's in here...
WAIT 2
GIVE T3000
GOTO LINK 24,0,0
END

@warmwelcome
1: Ahh, it is good to see you have a golden soul.
1: Has he sent for you?
H: "He?" Who's that?
1: Nothing. I have said too much already.
GIVE T3000
GOTO @pass
END

@pass
1: You may proceed.
WAIT 2
GOTO LINK 24,0,0

;--------------------------------------
;
SCENE 1001, forest, SCENE, "Gate to the Masters' Camp"
GIVE L9999
GIVE M9999
ACTOR 1, "Forest Guard", campguard, 1,30,70
IF T3008, @canpass
IF T3001, @normal
1: I see you have made it through the forest.
1: Don't get cocky just yet, you still have to pass...
1: The "Test of the Elements!"
H: "Test of the Elements?" What's that?
1: It is an ancient ritual.
1: For one to pass, they must be a balanced soul.
1: They must be strong, but not lack in wisdom.
1: You must the courage to go on, but must wait for the right time for it to come.
1: You must embrace life with full knowledge that there is dealth.
1: Only once these skills are mastered may you enter.
1: We shall begin the tests now...
SET test1, "Test of Knowledge"
SET test2, "Test of Strength"
SET test3, "Test of Courage"
SET test4, "Test of Patience"
SET test5, "Test of Life"
SET test6, "Test of Death"
GIVE T3001
@normal
IF T3002+T3003+T3004+T3005+T3006+T3007, @beatentests
1: These are the tests...
WAIT 0.5
N: 1: #<test1>
N: 2: #<test2>
N: 3: #<test3>
N: 4: #<test4>
N: 5: #<test5>
N: 6: #<test6>
ASK 9999
IF Q1, @test1
IF Q2, @test2
IF Q3, @test3
IF Q4, @test4
IF Q5, @test5
IF Q6, @test6
GOTO @normal
END

@test1
IF T3002, @testpassed
1: So, you wish to test your knowledge?
1: Very well. Show me that you have knowledge by answering this question...
1: What is the name of the king of Euphoria?
ASK 9999
IF Qking^joe, @test1win
IF Qjoe, @test1win
1: I'm sorry, that answer is not right.
1: Try again soon.
GOTO @normal
END

@test1win
1: Yes, that is correct.
SET test1, *passed*
ADD testswon, 1
GIVE T3002
1: What test would you like to take now?
GOTO @normal
END

@test2
IF T3003, @testpassed
1: You wish to know if you are strong? Let us see here...
1: If you have slain at least 50 fiends, I shall let you pass.
COMPARE #<num.hostKills>, 50
IF= @test2passed
IF> @test2passed
1: I'm sorry, but you have not slain enough fiends. Your current number is #<num.hostKills>.
1: Try again once you have slain more beasts.
GOTO @normal
END

@test2passed
1: Good, you've slain #<num.hostKills> monsters.
SET test2, *passed*
GIVE T3003
ADD testswon, 1
1: What would you like to take now?
GOTO @normal
END

@test3
IF T3004, @testfinished
SET couragemeter, 0
1: So, you wish to know if you have the courage to go on?
1: Answer me these questions three!
1: Question 1: If you saw someone being chased by a monster, would you...
1: a) Run away.
1: b) Grab the person and run.
1: c) Kill the monster.
@askquestion1
ASK 9999
IF Qa, @question1add1
IF Qb, @question1add2
IF Qc, @question1add3
1: say a, b, or c.
GOTO @askquestion1

@question1add1
1: I see... Interesting...
ADD couragemeter, 1
GOTO @question2

@question1add2
1: An interesting tactic...
ADD couragemeter, 2
GOTO @question2

@question1add3
1: Hmm.. I see...
ADD couragemeter, 3
GOTO @question2

@question2
1: Question 2: You confront Omega. What do you say?
1: a) This shall be a grand fight!
1: b) You shall not live another moment!
1: c) Umm... can we talk this over?
@askquestion2
ASK 9999
IF Qa, @question2add2
IF Qb, @question2add3
IF Qc, @question2add1
1: say a, b, or c.
GOTO @askquestion2

@question2add2
1: I see...
ADD couragemeter, 2
GOTO @question3

@question2add3
1: Hmm...
ADD couragemeter, 3
GOTO @question3

@question2add1
1: ...o...k...
ADD couragemeter, 1
GOTO @question3

@question3
1: Question 3: King Axl asks if you can do a dangerous task for him. What's your response?
1: a) I don't know...
1: b) What do I have to do?
1: c) Most certainly, my lord.
@askquestion3
ASK 9999
IF Qa, @question3add1
IF Qb, @question3add2
IF Qc, @question3add3
1: say a, b, or c.
GOTO @askquestion3

@question3add1
1: ...You're pathetic...
ADD couragemeter, 1
GOTO @decide

@question3add2
1: Hmm.. understandable...
ADD couragemeter, 2
GOTO @decide

@question3add3
1: I see....
ADD couragemeter, 3
GOTO @decide

@decide
1: ...
1: .....
COMPARE #<couragemeter>, 6
IF> @test3passed
1: You have failed the test.
1: Come back when you are more couragious.
GOTO @normal

@test3passed
1: Congradulations, you have passed the test.
SET test3, *passed*
GIVE T3004
ADD testswon, 1
1: What test would you like to take now?
GOTO @normal

@test4
IF T3005, @testpassed
1: So.. you want to know if you are patient...
WAIT 30
1: Congradulations, you have passed the test.
SET test4, *passed*
GIVE T3005
ADD testswon, 1
1: What test do you want to take now?
GOTO @normal
END

@test5
IF T3006, @testpassed
COMPARE #<test5mission>, 1
IF= @test5check
1: Life is a wonderful thing.
1: To live, you must have food.
1: Go out into the forest and gather 10 larva for me.
COMPARE #<num.item516>, 9
IF> @test5passed
SET test5mission, 1
1: Come back when you are done.
GOTO @normal

@test5check
COMPARE #<num.item516>, 9
IF> @test5passed
1: You still need to gather more larva, #<num.item516> isn't enough, I want 10.
GOTO @normal

@test5passed
1: Ahh, so you're found 10 larva.
1: I'll just take them now...
TAKE I516.10
SET test5, *passed*
GIVE T3006
ADD testswon, 1
1: Good. What test would you like to take now?
GOTO @normal
END

@test6
IF T3007, @testpassed
COMPARE #<test6mission>, 1
IF= @test6give
1: Death.. the oposite of life...
1: There is a peasant who lives in these woods.
COMPARE #<gaveG>, 1
IF= @test6gave
1: Find him and give him a generous amount of gold.
1: Return here when you have.
SET test6mission, 1
END

@test6give
COMPARE #<gaveG>, 1
IF= @test6passed
1: Go find the peasant and give him some money.
1: He is in this forest.
GOTO @normal
END

@test6gave
H: I have already given him my money.
1: This is good news.
GOTO @test6passed

@test6passed
1: So, you have given the peasent some money.
GIVE T3007
SET test6, *passed*
ADD testswon, 1
1: What test would you like to take now?
GOTO @normal
END

@testpassed
1: You have already passed this test.
GOTO @normal

;-------------------------------------------
@beatentests
1: So, you've beaten all the tests.
1: Very well, you may pass now.
1: Here are some boots that you can use to get to the camp more easily.
WAIT 3
N: *Got Boots of Forest Crossing!*
1: Well, go on then.
1: Farewell!
WAIT 1
GIVE T3008
GIVE I517
GOTO LINK 25,0,0
END

@canpass
1: You may proceed.
WAIT 1
GOTO LINK 25,0,0
END

;------------------------------------------------------
SCENE 1002, masterscamp, SCENE, "Old Man's Shop"
ACTOR 1, "Old Man", oldman, 1,20,90
1: Welcome sonny boy...
@normal
;GOTO @normalsell
1: Would you like to buy or sell?
WAIT 1
MENU "Buy=@normalsell""Sell=@normalbuy"
GOTO @normal
END

@normalsell
COMPARE #<oldmanshop>, 1
IF= @normalsell2
1: I bet you could use some items!
H: What kind of items have you got?
1: Ooh, exotic items from all around the world! Things you can't find anyplace else!
H: Well, that sounds good, I guess.
1: Oh, yes it is!
1: And they only cost a low fee starting at 1 million gold!
H: One million?! You have to be INSANE!
1: Fear not, sonny boy, you will get a grand use out of my items!
SET item1, "Boots of Loneliness"
SET item2, "Ultra Ability Token"
SET oldmanshop, 1
@normalsell2
1: What would you like to buy?
WAIT 1
N: 1: #<item1>
N: 2: #<item2>
N: 3: Upgrade Boots of Mountain Climbing
ASK 9999
IF Q1, @item1
IF Q2, @item2
IF Q3, @item3
1: 1, 2, or 3 sonny boy.
GOTO normalsell
END

@item1
IF I518, @alreadybought
1: Ahh, what a grand choice. These boots keep you from EVER entering a battle.
1: Of course, something this great comes with a hefty price...
1: I won't let it go for any less than 50 million gold!
H: Are you insane?!
1: That's the price. Do you want them or not?
ASK 9999
IF YES, @item1yes
H: No way, you've got to be crazy!
1: Suit yourself.
GOTO @normalsell
END

@item1yes
H: That sounds pretty good...
COMPARE #<money>, 50000000
IF< @tooexpensive
1: Alright then! I'll just subtract the money...
SUB money, 50000000
GIVE I518
SET item1, "*Out of Stock*"
1: There you go! Thanks, sonny!
H: /a sighs at the cost
1: Ehehe!
GOTO @normalsell

@item2
1: So, you'd like an ultra ability token?
1: Ok! Just 250000 gold...
H: Why can't you have a decent price?
1: That's the cost! Do you want it?
ASK 9999
IF YES @item2yes
H: No way!
1: Ok...
GOTO @normalsell
END

@item2yes
H: Very well, I suppose.
COMPARE #<money>, 250000
IF< @tooexpensive
1: Great!
1: Here ya go!
SUB money, 250000
GIVE I513
1: Use it well, sonny!
GOTO @normalsell
END

@item3
IF I608, @alreadybought
1: So, you'd like your boots of mountain climbing to be upgraded?
1: I can make them Level 25 boots with 25 attack and 75 defense for half a million gold.
1: Do we have a deal?
ASK 9999
IF YES, @item3yes
H: No, that's quite alright.
1: Very well.
GOTO @normalsell
END

@item3yes
H: Sure, that sounds great.
COMPARE #<money>, 500000
IF< @tooexpensive
1: Grand. If you'll just hand me those boots...
1: Here you go!
SUB money, 500000
GIVE I608
TAKE I600
GOTO @normalsell
END

@tooexpensive
1: You can't afford it!
GOTO @normalsell
END

@alreadybought
1: You already have that!
GOTO @normalsell
END

@normalbuy
COMPARE #<oldmanshop2>, 1
IF= @vercheck
1: Here's the deal.
1: I buy all items that you can't sell anywhere else for 5000 gold.
1: You cannot (as of yet) get this back, so only do this if you are not using the equipment.
SET oldmanshop2, 1
@vercheck
GOTO @normalbuy2
1: You must have A70 to continue.
1: Come back when you have upgraded Well of Souls.
GOTO @normal
END
@normalbuy2
1: Let's see what you have...
IF I303, @normalbuy303
IF I400, @normalbuy400
IF I401, @normalbuy401
IF I403, @normalbuy403
IF I404, @normalbuy404
IF I405, @normalbuy405
IF I406, @normalbuy406
IF I509, @normalbuy509
IF I520, @normalbuy520
IF I527, @normalbuy527
IF I700, @normalbuy700
@normalbuynormal
1: Looks like you've got nothing I need.
GOTO @normal
END

@normalbuy303
SET currentsell,303
SET currentitem, "Wompas Claw"
SET currentnext,400
GOTO @normalbuyask

@normalbuy400
SET currentsell,400
SET currentitem, "Cracked Healing Wand"
SET currentnext,401
GOTO @normalbuyask

@normalbuy401
SET currentsell,401
SET currentitem, "Deconfusion Wand"
SET currentnext,403
GOTO @normalbuyask

@normalbuy403
SET currentsell,403
SET currentitem, "Wide-Range Healing Wand"
SET currentnext,404
GOTO @normalbuyask

@normalbuy404
SET currentsell,404
SET currentitem, "King's Staff"
SET currentnext,405
GOTO @normalbuyask

@normalbuy405
SET currentsell,405
SET currentitem, "Wand of Stunning"
SET currentnext,406
GOTO @normalbuyask

@normalbuy406
SET currentsell,406
SET currentitem, "Sap Wand"
SET currentnext,509
GOTO @normalbuyask

@normalbuy509
SET currentsell,509
SET currentitem, "Super Cool Boots"
SET currentnext,520
GOTO @normalbuyask

@normalbuy520
SET currentsell,520
SET currentitem, "The Force"
SET currentnext,527
GOTO @normalbuyask

@normalbuy527
SET currentsell,527
SET currentitem, "Wise Blade"
SET currentnext,700
GOTO @normalbuyask

@normalbuy700
SET currentsell,700
SET currentitem, "Purple Robe of Defense"
SET currentnext, "normal"
GOTO @normalbuyask

@normalbuyask
N: If you wish to sell #<currentitem>, type #<currentsell> right now.
N: If not, type something besides #<currentsell> to
N: see if you have the next item wanted by the old man.
ASK 9999
STRCMP #<lastAsk>, #<currentsell>
IF=, @normalbuydoit
GOTO @normalbuy
END

@normalbuydoit
N: #<currentitem> has been sold for 5000 gold.
TAKE I#<currentsell>
GIVE G5000
GOTO @normalbuy
END
;-----------------------------------------------
;
SCENE 1003 masterscamp, SCENE, "Masters' Hut"
ACTOR 1, "Simmen Stenil", ss, 1,60,80
ACTOR 2, "Gandalf the White", dom, 1,40,60
MUSIC masters.mid
SEL 2
POSE 4
IF T3024, @quest4
IF T3023, @quest3over
IF T3022, @quest3on2
IF T3021, @quest3on
IF T3020, @quest3begin2
IF T3018, @quest3begin
IF T3017, @oblion
IF T3016, @quest2over
IF T3015, @quest2on
IF T3012, @quest2begin
IF T3011, @quest1over
IF T3010, @quest1on
IF T3009, @quest1begin
1: So you have come....
2: Yes... we have heard tales of your journeys.
H: I've heard of you! You're the masters!
1: Yes, that we are.
2: Listen %1, we have heard tales of your journeys, and we'd like to get your help.
1: Every so often, we'll have a task for you.
2: Keep in mind these tasks are dangerous, and that you do not have to take part in them. But remember...
1: ...taking part in these quests offers great rewards.
2: So, now you know what we ask of you.
1: Do you wish to help up?
2: Or shall you leave and keep to the main story? (HELP/LEAVE)
ASK 9999
IF YES, @begincont
IF Qhelp, @begincont
1: Ahh, I understand.
2: Please come back if you ever change your mind.
END

@begincont
GIVE T3009
1: Grand. We deeply appreciate it.
2: Yes, and we already have things for you to do!
;
;
@quest1begin
1: Recently, we've....
2: Umm... well...
H: What is it?
1: You know...
2: We could really go for some of...
1: ... Lady Jane's Cookies....
2: They're simply the best.
1: It's kind of embarassing to ask, but could you go and get us a sack of cookies?
2: It'd be deeply appreciated...
H: Is this going to be the basis of ALL my quests?
1: No, oh no!
2: Just this once! Honest!
H: *sigh* Alright then, I suppose I could go and get you some cookies.
1: Alright! Hurry back!
2: Hopefully we'll have a REAL quest next time you come...
GIVE T3010
END

@quest1on
1: Have you gotten the cookies yet?
2: We are wanting those things!
H: Not yet...
1: Hurry!
2: We cannot wait much longer!
END

@quest1over
1: Have you gotten the cookies?
H: Yes! Here they are!
2: Cookies!
WAIT 2
N: Simmen Stenil and Gandalf gnaw at the cookies until there is nothing left, not even a crumb.
WAIT 2
1: Well, that was quite good.
2: Yes, and I suppose we can give you a REAL mission now.
GIVE T3012
TAKE I305
;
;
@quest2begin
1: Well, now that that's over with, we have something you'd like you to do.
2: Most of the quests we are going to send you on involve danger.
1: So, for this quest, we're going to get you to slay a powerful green elf.
2: If you can come back with proof of your victory, then I shall allow you entrance to a dangerous zone.
1: This green elf can be hard to find.
2: Right now, he's living in the secret area of the Gabonasian Mountains.
1: Just run into a battle and he might show up.
2: Go on, now!
GIVE T3015
END

@quest2on
1: Have you slain the elf yet?
H: No, not yet.
2: Get to it!
END

@quest2over
1: Have you any proof of the elf's defeat?
H: Yes, he gave me The Force!
2: What? But how?
H: It's right here....
1: Interesting.
2: Well, it looks like you could wear it...
1: Yes, why don't you try and use it as an amulet?
2: It looks pretty powerful...
1: Well, now that the elf is gone, we can tell you about the secret area!
2: Yes, let us begin!
TAKE I519
GIVE I520
GIVE T3017
;
;
@oblion
1: So, you're fit to go into the forest....
2: Alright, follow us!
WAIT 2
GOTO SCENE 156
END

@quest3begin
1: Welcome back, %1.
2: Lately, King Joe has grown worried.
1: He cannot sleep at night, as he hears noises...
2: We don't understand it, but, if you don't mind, could you go and ask him about it?
1: I'm sure you could help him out.
2: When you've talked to him, come back here and we'll discuss what to do next.
GIVE T3020
END

@quest3begin2
1: Did you talk to King Joe about his problem yet?
H: No, not yet.
2: Well then, how are you supposed to solve it by standing around here?
1: Get to it!
END

@quest3on
1: What did King Joe say?
H: There are sounds coming from around his statue.
2: Hmm... interesting... Here, why don't you take this statue we found?
1: It has "KJC" written on the bottom... maybe it links with the noises?
2: Well, go ahead and take this to King Joe.
1: Farewell, %1!
GIVE I306
GIVE T3022
END

@quest3on2
1: Please, take that statue to King Joe.
2: He needs your help!
END

@quest3over
H: I was able to find out the source of the noise.
H: Now I must eliminate the cultists...
1: That's good. It's nice to know that we could rely on you.
2: Yes, and it is.
GIVE T3024
;
;
@quest4
1: Sorry, we don't have any more quests for you right now.
2: Come back next version!
END


;--------------------------------------
;
SCENE 1004, oblianforest, SCENE, "Gates to Oblian Forest"
ACTOR 1, "Simmen Stenil", ss, 1,80,90
ACTOR 2, "Gandalf", dom, 4,65,80
SEL 1
FACE 1
SEL 2
FACE 2
1: Well, looks like we've made it.
2: Yes, thank goodness.
1: Huh... I hear something.....
2: It's coming this way!
1: %1, be careful!
2: What... is that a....
1: Zhimzhapian?
2: Look out!
WAIT 1
MOVE 1,-100,-100,1
MOVE 2,-100,-100,1
FIGHT -514,-513,516
H: Whoa, what was that thing?
MOVE 1,80,90,1
MOVE 2,65,80,1
1: That was just one of the many enemies that are in this forest.
2: Be careful!
1: Well then, now that we've led you in, you're free to roam around.
H: Hey! Aren't you all coming?
2: No, we need to return to the camp.
1: We shall be waiting there if you want more things to do.
2: Goodbye %1!
MOVE 1,110,90
MOVE 2,110,80
H: Farewell.
H: Well, I might as well head in!
WAIT 2
GIVE T3018
GOTO LINK 26,0,0
END

SCENE 1005 oblian, SCENE, "Healing Spot"
GIVE L9999
GIVE M9999
N: HP/MP restored!
END